EjrALGinterseccion01

Para ayudarnos construimos el isomorfismo que nos lleva las matrices 2x2 a vectores de cuatro componentes y su inverso.

(%i2)

define( Isom( m), flatten( makelist( makelist( m[ i, j], j, 1, 2), i, 1, 2))) $
define( InvIsom( v), matrix([ v[ 1], v[ 2]],[ v[ 3], v[ 4]])) $

Nos dicen que $S=\textbf{Gen}\{[[1,2],[2,1]], [[0,-1],[1,1]]\}$ $\in\mathcal{M}_2(\mathbb{R})$ y
$T=\textbf{Gen}\{[[-1,0],[3,-1]],[[1,9],[9,-2]]\}\in\mathcal{M}_2(\mathbb{R})$.
Construyamos las matrices que nos ayudarán a obtener las ecuaciones implícitas:

(%i5)

s1 : matrix([ 1, 2],[ 2, 1]) $
s2 : matrix([ 0, - 1],[ 1, 1]) $
S : transpose( matrix( Isom( s1), Isom( s2),[ x, y, z, t])) ;

\begin{matrix} (S) & [\begin{matrix} 1 & 0 & x \\ 2 & - 1 & y \\ 2 & 1 & z \\ 1 & 1 & t \end{matrix}] \end{matrix}

Como la dimensión de S es 2, necesitaremos un menor de orden dos distinto de cero, y el resto de menores de orden tres serán los que nos definan las ecuaciones implícitas:

(%i6)

eqS : rat([ determinant( submatrix( 4, S)) = 0, determinant( submatrix( 3, S)) = 0], t, z, y, x) ;

\begin{matrix} (eqS) & [4 x - y - z = 0, 3 x - y - t = 0] \end{matrix}

Repitamos el proceso para el subespacio T:

(%i10)

t1 : matrix([ - 1, 0],[ 3, - 1]) $
t2 : matrix([ 1, 9],[ 9, - 2]) $
T : transpose( matrix( Isom( t1), Isom( t2),[ x, y, z, t])) ;
eqT : rat([ determinant( submatrix( 4, T)) = 0, determinant( submatrix( 3, T)) = 0], t, z, y, x) ;

\begin{matrix} (T) & [\begin{matrix} - 1 & 1 & x \\ 0 & 9 & y \\ 3 & 9 & z \\ - 1 & - 2 & t \end{matrix}] \end{matrix}

\begin{matrix} (eqT) & [- 27 x + 12 y - 9 z = 0, 9 x - 3 y - 9 t = 0] \end{matrix}

La intersección de ambos subespacios será el resultado de un sistemas con todas las ecuaciones:

(%i11)

sol : linsolve( join( eqS, eqT),[ x, y, z, t]) ;

\begin{matrix} solve: dependent equations eliminated: (4) \end{matrix}

\begin{matrix} (sol) & [x = %r1, y = 3 %r1, z = %r1, t = 0] \end{matrix}

Mostremos sus ecuaciones paramétricas:

(%i13)

v : ev([ x, y, z, t], ev( sol, %rnum_list[ 1] = 1)) $
print( InvIsom([ x, y, z, t]), "=λ", InvIsom( v)) $

\begin{matrix} [\begin{matrix} x & y \\ z & t \end{matrix}] =λ [\begin{matrix} 1 & 3 \\ 1 & 0 \end{matrix}] \end{matrix}

Sus ecuaciones implícitas:

(%i18)

ST : transpose( matrix( v,[ x, y, z, t])) $
eq1 : determinant( submatrix( 2, 3, ST)) = 0 $
eq2 : determinant( submatrix( 2, 4, ST)) = 0 $
eq3 : determinant( submatrix( 3, 4, ST)) = 0 $
print( "S+T={", InvIsom([ x, y, z, t]), ";", eq1, ", ", eq2, ", ", eq3, "}") $

\begin{matrix} S+T= {[\begin{matrix} x & y \\ z & t \end{matrix}]; t = 0, z - x = 0, y - 3 x = 0} \end{matrix}

Created with wxMaxima.