EjrALGautovectores04

Para este ejercicio necesitamos calcular todos sus autovalores y sus autovectores. Designemos la matriz y determinemos su ecuación característica:

(%i3)

A : matrix([ 1, - 1, 4],[ 3, 2, - 1],[ 2, 1, - 1]) ;
eq : ratsimp( determinant( A - x * ident( 3))) $
print( "Ecuación característica:", eq = 0) $

\begin{matrix} (A) & [\begin{matrix} 1 & - 1 & 4 \\ 3 & 2 & - 1 \\ 2 & 1 & - 1 \end{matrix}] \\ Ecuación característica: - x^{3} + 2 x^{2} + 5 x - 6 = 0 \end{matrix}

Las soluciones de la ecuación característica nos determinan los autovalores:

(%i4)

solve( eq) ;

\begin{matrix} (%o4) & [x = 3, x = - 2, x = 1] \end{matrix}

Tenemos tres autovalores distintos, por tanto habrá tres autovectores distintos. Veámoslos:

(%i6)

X :[ x, y, z] $
eq :( A - 3 * ident( 3)). transpose( matrix( X)) ;

\begin{matrix} (eq) & [\begin{matrix} 4 z - y - 2 x \\ - z - y + 3 x \\ - 4 z + y + 2 x \end{matrix}] \end{matrix}

(%i8)

sist : flatten( makelist( row( eq, i)[ 1], i, 1, 3)) $
sol : linsolve( sist, X) ;

\begin{matrix} solve: dependent equations eliminated: (3) \end{matrix}

\begin{matrix} (sol) & [x = %r1, y = 2 %r1, z = %r1] \end{matrix}

Como habíamos previsto, tenemos un solo parámetro. Ahora, evaluamos de la forma habitual para obtener los autovectores:

(%i9)

v_3 : ev( X, ev( sol, %rnum_list[ 1] = 1)) ;

\begin{matrix} (v_3) & [1, 2, 1] \end{matrix}

Verifiquemos que es el autovector buscado:

(%i10)

makelist( print( A, v, "=", A. v, "=", 3, "·", v), v,[ transpose( v_3)]) $

\begin{matrix} [\begin{matrix} 1 & - 1 & 4 \\ 3 & 2 & - 1 \\ 2 & 1 & - 1 \end{matrix}] [\begin{matrix} 1 \\ 2 \\ 1 \end{matrix}] = [\begin{matrix} 3 \\ 6 \\ 3 \end{matrix}] = 3 \cdot [\begin{matrix} 1 \\ 2 \\ 1 \end{matrix}] \end{matrix}

Repitamos el proceso con los siguientes autovalores:

(%i15)

eq :( A + 2 * ident( 3)). transpose( matrix( X)) $
sist : flatten( makelist( row( eq, i)[ 1], i, 1, 3)) $
sol : linsolve( sist, X) $
v_2 : ev( X, ev( sol, %rnum_list[ 1] = 1)) ;
makelist( print( A, v, "=", A. v, "=", - 2, "·", v), v,[ transpose( v_2)]) $

\begin{matrix} solve: dependent equations eliminated: (3) \end{matrix}

\begin{matrix} (v_2) & [- 1, 1, 1] \\ [\begin{matrix} 1 & - 1 & 4 \\ 3 & 2 & - 1 \\ 2 & 1 & - 1 \end{matrix}] [\begin{matrix} - 1 \\ 1 \\ 1 \end{matrix}] = [\begin{matrix} 2 \\ - 2 \\ - 2 \end{matrix}] = - 2 \cdot [\begin{matrix} - 1 \\ 1 \\ 1 \end{matrix}] \end{matrix}

(%i20)

eq :( A - 1 * ident( 3)). transpose( matrix( X)) $
sist : flatten( makelist( row( eq, i)[ 1], i, 1, 3)) $
sol : linsolve( sist, X) $
v_1 : ev( X, ev( sol, %rnum_list[ 1] = 1)) ;
makelist( print( A, v, "=", A. v), v,[ transpose( v_1)]) $

\begin{matrix} solve: dependent equations eliminated: (3) \end{matrix}

\begin{matrix} (v_1) & [- 1, 4, 1] \\ [\begin{matrix} 1 & - 1 & 4 \\ 3 & 2 & - 1 \\ 2 & 1 & - 1 \end{matrix}] [\begin{matrix} - 1 \\ 4 \\ 1 \end{matrix}] = [\begin{matrix} - 1 \\ 4 \\ 1 \end{matrix}] \end{matrix}

Solo nos resta calcular sus normas:

(%i21)

makelist( sqrt( v. v), v,[ v_3, v_2, v_1]) ;

\begin{matrix} (%o21) & [\sqrt{6}, \sqrt{3}, 3 \sqrt{2}] \end{matrix}

La mayor de sus normas es:

(%i22)

lmax( %) ;

\begin{matrix} (%o22) & 3 \sqrt{2} \end{matrix}

Created with wxMaxima.